1. 1
2. 2
3. 3
4. 4
5. 5
6. 6
7. 7
8. 8
9. 9
10. 10
11. 11
12. 12
13. 13
14. 14
15. 15
16. 16
17. 17
18. 18
19. 19
20. 20
21. 21
22. 22
23. 23
24. 24
25. 25
26. 26
27. 27
28. 28
29. 29
30. 30
31. 31
32. 32
33. 33
34. 34
35. 35
36. 36
37. 37
38. 38
39. 39
40. 40
41. 41
42. 42
43. 43
44. 44
45. 45
46. 46
47. 47
48. 48
49. 49
50. 50
51. 51
52. 52
53. 53
54. 54
55. 55
56. 56
57. 57
58. 58
59. 59
60. 60
61. 61
62. 62

{
  description = "An OpenTTD-like game written in Lean";

  inputs = {
    # TODO: Change this back to nixos-unstable once it gets lean4 v4.32.0
    nixpkgs.url = "github:jthulhu/nixpkgs/lean-update-4.32";
    nixgl = {
      url = "github:nix-community/nixGL";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      nixgl,
    }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ nixgl.overlay ];
      };
    in
    {
      packages.${system}.default = pkgs.leanPackages.buildLakePackage {
        pname = "monotonicity";
        src = self;
        version = "0.1";
        lakeHash = "sha256-kuWXGJ416kzJlf0v6xztoleMfEIUUC3WgN0bEiANfM4=";
        buildInputs = [ pkgs.raylib ];
        # This fixes a linker error
        hardeningDisable = [ "bindnow" ];
        postConfigure = ''
          # Make sure the linker can find libraylib.so
          substituteInPlace lakefile.toml --replace-fail \
            '["-lraylib"]' \
            '["-L${pkgs.raylib}/lib", "-lraylib"]'
          # Patch Raylean for FFI stuff
          cd .lake/packages/raylean
          patch -p1 < ../../../raylean.patch
          cd -
        '';
      };
      apps.${system}.default =
        let
          # Use nixGL for running this on non-NixOS
          # This needs `--impure` because of Nvidia nonsense
          wrapper = pkgs.writeShellScript "monotonicity" ''
            exec ${pkgs.nixgl.auto.nixGLDefault}/bin/nixGL ${pkgs.rlwrap}/bin/rlwrap ${
              self.packages.${system}.default
            }/bin/monotonicity "$@"
          '';
        in
        {
          type = "app";
          program = "${wrapper}";
        };
      formatter.${system} = pkgs.nixfmt-tree;
    };
}